CSV×SQLテクニック：VBAで二つのCSVファイルから最大値と最小値をSQLで取得する方法

Excel VBAでSQLを使い、2つのCSVファイルの最大値・最小値を調べる方法を紹介します。

※「C:¥Temp」フォルダーをデータベースと見なします。

① 「Microsoft Office 16.0 Access database engine Object Library」を参照設定します。

② 参照設定したことで、DAOを利用できます。Excel ブックを用意して、標準モジュールに DAO を利用した次のコードを記載します。

二つのCSVファイルをUNION ALLでくっつけて、SQLのMAXとMIN関数を使います！

Option Explicit

Public Sub Sample_Select2Table_DAO_01()

    ' DAO データベース設定用変数
    Dim db As DAO.Database

    ' DAO レコードセット設定用変数
    Dim rs As DAO.Recordset

    ' 単純なループカウンタ
    Dim lp As Long

    ' 検索結果表示用文字列
    Dim str As String

    ' "C:\Temp"をデータベースとして開く。
    Set db = DBEngine.Workspaces(0).OpenDatabase( _
    "C:\Temp" _
    , False _
    , False _
    , "Text;DataBase=C:\Temp;HDR=YES" _
    )

    ' レコードセットを取得する。
    Set rs = db.OpenRecordset( _
                    Name:=" SELECT MAX(PRICE), MIN(PRICE) " _
            & " FROM (SELECT * FROM [Data#csv] UNION ALL SELECT * FROM [Data2#csv] ) " _
        , Type:=dbOpenDynaset _
    )
    ' 対象レコードが１件以上存在するか調べる。
    If rs.EOF Then

    str = "(検索結果：０件)"

    Else

    ' 検索できる全てのレコードを参照する。
    Do Until (rs.EOF)

    ' 全ての検索結果をカンマ区切りで連結する。
    str = str & rs.Fields(0)

    For lp = 2 To rs.Fields.Count
        str = str & "," & rs.Fields(lp - 1)
    Next lp

    str = str & vbLf

    ' 次のレコードに移る。
    rs.MoveNext

    Loop

    End If

    ' カーソルを閉じる。
    rs.Close
    Set rs = Nothing

    ' データベースを閉じる。
    db.Close
    Set db = Nothing

    ' 検索結果を表示する。
    MsgBox str, vbOKOnly

End Sub

③ Sample_Select2Table_DAO_01を実行します。